*Copyright @ www.statschoice.com;

/********************************************************************************

What is the word meaning of 'array'?

********************************************************************************/

/********************************************************************************

an indexed set of related elements.

********************************************************************************/

/********************************************************************************

What do we mean by 'array' and 'array processing' in SAS?

********************************************************************************/

/********************************************************************************

Array: An array is a temporary grouping of SAS variables that are arranged in a particular order and identified by a name
Array processing: perform one or more tasks for a series of related variables.

********************************************************************************/

/********************************************************************************

Create input data

********************************************************************************/

data scores;
      infile cards truncover;
      input usubjid$ visit$ score1 score2 score3;
  cards;
  1001 Week1 10 20 30
  1001 Week2 9 20 29
  1001 Week3 . . 25
  1001 Week4 . . .
  1001 Week5 10 15 .
  1001 Week6 10 20 30
  ;
  run;

/********************************************************************************

Replace missing values in variables containing scores - using if then else

********************************************************************************/

data output;
      set scores;
      if missing(score1) then score1=0;
      if missing(score2) then score2=0;
      if missing(score3) then score3=0;
  run;

/********************************************************************************

Replace missing values in variables containing scores - using arrays

********************************************************************************/

data output;
      set scores;
      array scores[3] score1 score2 score3;
   
      do i=1 to 3;
          if missing(scores[i]) then scores[i]=0;
      end;
  run;

/********************************************************************************

Create a separate row for each score variable and store then individual score in a variable named score - using output statements

********************************************************************************/

data output;
      set scores;
   
      score=score1;
      output;
      score=score2;
      output;
      score=score3;
      output;
  run;

/********************************************************************************

Create a separate row for each score variable and store then individual score in a variable named score - using arrays

********************************************************************************/

data output;
      set scores;
      array scores[3] score1 score2 score3;
   
      do i=1 to 3;
          score=scores[i];
          output;
      end;
  run;