*Copyright @ www.statschoice.com;

/********************************************************************************

Create sample datasets

********************************************************************************/

 
  data class01;
    set sashelp.class;
  run;
   
  data class02;
    set sashelp.class;
    if age=16 then do;
        sex="";
    end;
  run;

/********************************************************************************

proc freq with all defaults

********************************************************************************/

/********************************************************************************

uses the recently created dataset as the data= option is not used
gives one way frequencies of unique values in all variables - both numeric and character variables
output can be seen in output/results window - no dataset is created
default stats provided in output window are: frequency, percentage, cumulative frequency and cumulative percentage
a separate table is created for each variable in the output window

********************************************************************************/

proc freq;
  run;

/********************************************************************************

using data= option to mention the input dataset

********************************************************************************/

proc freq data=class01;
  run;

/********************************************************************************

using tables statement to request frequencies for a specific variable

********************************************************************************/

proc freq data=class01;
    tables sex;
  run;

/********************************************************************************

using tables statement to request frequencies for multiple individual variables

********************************************************************************/

/********************************************************************************

list the variables separated by a space in the table statment

********************************************************************************/

proc freq data=class01;
    tables sex age;
  run;

/********************************************************************************

using multiple table statments

********************************************************************************/

 
  proc freq data=class01;
    tables sex;
    tables age;
  run;

/********************************************************************************

using by group processing to obtain frequencies of a variable grouped by another variable

********************************************************************************/

/********************************************************************************

use by statment for the grouping variable
pre sort the dataset by using sort procedure
separate table is created for each unique value in the by group variable

********************************************************************************/

proc sort data=class01 out=class_sort;
    by sex;
  run;
   
  proc freq data=class_sort;
    by sex;
    table age;
  run;

/********************************************************************************

cross-tabulation to obtain frequencies of a variable grouped by another variable

********************************************************************************/

/********************************************************************************

list the variables separated by an asterisk
the unique values of first listed variable variable appear as rows
the unique values of second listed variable variable appear as columns
A row for row totals and column for column totals will also be displayed
frequency, percent, rowpercent and columnpercent appear in the cells created at intersection of row and column values

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age;
  run;

/********************************************************************************

cross tabulation of more than two variables

********************************************************************************/

/********************************************************************************

a separate table is created for each unique value in the first listed variable
the unique values of second listed variable variable appear as rows
the unique values of third listed variable variable appear as columns

********************************************************************************/

 
  data class_agegroup;
    set class01;
    length age_group $10;
    if age lt 13 then age_group="Pre-teen";
    else if age lt 19 then age_group="Teen";
  run;
   
  proc freq data=class_agegroup;
    tables age_group*age*sex;
  run;

/********************************************************************************

options to control the stats displayed in output window

********************************************************************************/

/********************************************************************************

one way tables - default

********************************************************************************/

proc freq data=class01;
    tables sex;
  run;

/********************************************************************************

one way tables - suppress cumultative stats

********************************************************************************/

 
  proc freq data=class01;
    tables sex/nocum;
  run;

/********************************************************************************

one way tables - suppress percent

********************************************************************************/

 
  proc freq data=class01;
    tables sex/nopercent; *notice that percent and cumulative percentages are suppressed;
  run;

/********************************************************************************

one way tables - suppress count

********************************************************************************/

/********************************************************************************

there exists no such option to suppress count

********************************************************************************/

proc freq data=class01;
    tables sex/nocount;
  run;

/********************************************************************************

one way tables - suppress multiple possible elements

********************************************************************************/

/********************************************************************************

list the options seen above separated by a space

********************************************************************************/

 
  proc freq data=class01;
    tables sex/nopercent nocum;
  run;

/********************************************************************************

n-way tables - default

********************************************************************************/

/********************************************************************************

default stats: frequency, percentage, column percentage, row percentage

********************************************************************************/

 
  proc freq data=class01;
    table sex*age;
  run;

/********************************************************************************

n-way tables - suppress percentage

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/nopercent;
  run;

/********************************************************************************

n-way tables - suppress row percentage

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/norow;
  run;

/********************************************************************************

n-way tables - suppress column percentage

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/nocol;
  run;

/********************************************************************************

n-way tables - suppress both row and column percentage

********************************************************************************/

/********************************************************************************

list the above used options separated by space

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/norow nocol;
  run;

/********************************************************************************

n-way tables - suppress both row and column percentage and also suppress (total) percetage

********************************************************************************/

/********************************************************************************

list the above used options separated by space

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/norow nocol nopercent;
  run;

/********************************************************************************

option to change the tabular view of n-way tables to list view (view all the levels across variables as columns)

********************************************************************************/

 
  proc freq data=class01;
    tables sex*age/list;
  run;

/********************************************************************************

option to save the frequencies and percentages into a dataset

********************************************************************************/

/********************************************************************************

we need to use out= option on table(s) statement to save the stats into a dataset
by default all the variables listed on table statement and count, percentage are present in dataset
the default results continue to be displayed in the output/results window along the creation of dataset

********************************************************************************/

 
  proc freq data=class01;
    table sex/out=counts01;
  run;

/********************************************************************************

any of the options (nopercent, nocum, nocol, nrow,list) used to suppress stats are applicable only for results displayed in output window

********************************************************************************/

proc freq data=class01;
    table sex/out=counts02 nopercent nocum;
  run;

/********************************************************************************

out= option on n-way table

********************************************************************************/

 
  proc freq data=class01;
    table sex*age/list out=counts03;
  run;
   
  proc freq data=class_agegroup;
    table age_group*age*sex /list out=counts04;
  run;

/********************************************************************************

using noprint option on proc freq statement

********************************************************************************/

/********************************************************************************

when creating a dataset for stats we may not be interested in seeing the results in output window
in such cases, we can use noprint option on proc freq statement to suppress the results in output window

********************************************************************************/

 
  proc freq data=class01 noprint;
    table sex*age/out=counts05;
  run;

/********************************************************************************

mutliple one-way tables on tables statment with out= option

********************************************************************************/

/********************************************************************************

output dataset will be created for the last table requested - sex in the first example
output dataset will be created for the last table requested - age in the second example

********************************************************************************/

 
  proc freq data=class01 noprint;
    table age sex/out=counts06;
  run;
   
  proc freq data=class01 noprint;
    table sex age/out=counts07;
  run;

/********************************************************************************

multiple n-way tables on tables statement with out=option

********************************************************************************/

/********************************************************************************

output dataset will be created for the last table requested

********************************************************************************/

 
  proc freq data=class_agegroup noprint;
    table age_group*age sex*age/out=counts08; *sex*age in this example;
  run;
   
   
  proc freq data=class_agegroup noprint;
    table  sex*age age_group*age/out=counts09; *age_group*age in this example;
  run;

/********************************************************************************

create multiple datasets within the same procedure invocation

********************************************************************************/

/********************************************************************************

we need to use multiple table statements

********************************************************************************/

 
  proc freq data=class01 noprint;
    table sex/out=sex_counts;
    table age/out=age_counts;
  run;
   
  proc freq data=class_agegroup noprint;
    table sex*age/out=sex_age_counts;
    table age_group*age/out=age_group_age_counts;
  run;

97914
  97915   proc freq data=class01 noprint;
  97916      table sex/out=sex_counts;
  97917      table age/out=age_counts;
  97918   run;
   
  NOTE: There were 19 observations read from the data set WORK.CLASS01.
  NOTE: The data set WORK.SEX_COUNTS has 2 observations and 3 variables.
  NOTE: The data set WORK.AGE_COUNTS has 6 observations and 3 variables.
  NOTE: PROCEDURE FREQ used (Total process time):
        real time           0.03 seconds
        cpu time            0.03 seconds
   
   
  97919
  97920   proc freq data=class_agegroup noprint;
  97921      table sex*age/out=sex_age_counts;
  97922      table age_group*age/out=age_group_age_counts;
  97923   run;
   
  NOTE: There were 19 observations read from the data set WORK.CLASS_AGEGROUP.
  NOTE: The data set WORK.SEX_AGE_COUNTS has 11 observations and 4 variables.
  NOTE: The data set WORK.AGE_GROUP_AGE_COUNTS has 6 observations and 4 variables.
  NOTE: PROCEDURE FREQ used (Total process time):
        real time           0.01 seconds
        cpu time            0.00 seconds
   
   
  97924
  97925

/********************************************************************************

missing values in variables for which frequency tables are requested

********************************************************************************/

/********************************************************************************

missing values - results in output window

********************************************************************************/

/********************************************************************************

displays the total number of records with missing levels at the bottom of the table

********************************************************************************/

 
  proc freq data=class02;
    tables sex;
  run;
   
  proc freq data=class02;
    tables age*sex;
  run;

/********************************************************************************

include missing value as level in the table

********************************************************************************/

/********************************************************************************

missing option on tables statement

********************************************************************************/

proc freq data=class02;
    tables sex/missing;
    tables age*sex/missing;
  run;

/********************************************************************************

missing levels: impact on output dataset

********************************************************************************/

/********************************************************************************

missing values will be considered for levels creation and a separate row is created for that level
note that in the dataset, the percentages are calculated based on non-missing level counts and percentage is not calculated on missing levels

********************************************************************************/

proc freq data=class02;
    tables sex/out=sex_counts02;
    tables age*sex/out=age_sex_counts02;
  run;